*** Variables -- see the paper for detailed description
/*
orgname -- Name of organization
numbase -- Number of bases
gid -- A group's ID number
fail -- =1 if a group failed in a given year; =0 in 2007 if a group was active 
			by the end of sample period. We use this info to construct dependent var. later below
year -- Year
politym -- Polity2 variable
mem -- Military expenditure (% of GDP) 
ethnm -- Ethnic diversity
atropicm -- Tropic area (share of land territory in tropics)
landlock -- =1 if a base country is landlocked
eap -- East Asia and Pacific
eca -- Europe and Cantral Asia
lac -- Latin America and Caribbean
mena -- Middle East and North Africa
na -- North America
sas -- South Asia
ssa -- sub-Saharan Africa
lw -- Left wing
nat -- Nationalist
rw -- Right wind
rel -- Religious
compm -- Number of other groups based in a country
divers -- Attack diversity (transnational attacks)
lpop -- Log of population
ly -- Log of real per capita GDP
op -- Trade opennes (share of GDP) 
gov -- Government spending (share of GDP)
lsize -- Log of a group's size 
ttpk -- Number of transnational terrorist attacks per capita
tcpa -- Number of casualties per transnational attack
lelv -- Log of elevation
shtter -- Share of transnational attacks in total attacks
tottcpa -- Number of casualties per total (both trans and domestic) attack
diverstot -- Attack diversity (both domestic and transnational attacks) 
*/


**********************************
*** Prepare data
**********************************
	sort gid year
	by gid: gen t=_n
	gen dstar=0 
	replace dstar=1 if fail==1 /* construct dependent var. */
	
	gen x1=t
	gen x2=t^2	
	gen temp=1
	replace temp=2 if year>=1980
	replace temp=3 if year>=1990
	replace temp=4 if year>=2000
	xi i.temp


**********************************
*** Table 1: Descriptive stats
**********************************
su lsize lw nat rw rel ttpk tcpa numbase compm divers ly lpop op gov mem politym ///
	ethnm eap eca lac mena na sas ssa lelv atropicm landlock


*********************************
*** Tables 2-3
*********************************
	logit dstar x1 x2 lsize i.lw i.nat i.rw ttpk tcpa numbase compm divers ///
		ly lpop op gov politym ethnm c.ethnm#c.ethnm, rob
	est store Mod1
	margins, dydx(_all) atmean post
	est store ME1
	logit dstar x1 x2 lsize i.lw i.nat i.rw ttpk tcpa numbase compm divers ///
		ly lpop op gov politym ethnm c.ethnm#c.ethnm i.eap i.eca i.lac i.na i.sas i.ssa, rob
	est store Mod2
	margins, dydx(_all) atmean post
	est store ME2
	logit dstar _I* lsize i.lw i.nat i.rw ttpk tcpa numbase compm divers ///
		ly lpop op gov politym ethnm c.ethnm#c.ethnm i.eap i.eca i.lac i.na i.sas i.ssa, rob
	est store Mod3
	margins, dydx(_all) atmean post
	est store ME3	
	logit dstar _I* lsize i.lw i.nat i.rw ttpk tcpa numbase compm divers ///
		ly lpop op politym ethnm c.ethnm#c.ethnm mem i.eap i.eca i.lac i.na i.sas i.ssa, rob
	est store Mod4
	margins, dydx(_all) atmean post
	est store ME4

	esttab Mod*, b(3) se(3) stats(N ll r2_p) star(* 0.10 ** 0.05 *** 0.01)		/* Table 2 */
	esttab ME*, margin b(3) se(3) stats(N) star(* 0.10 ** 0.05 *** 0.01)		/* Table 3 */
	estimates clear


*********************************
*** Tables 4-5
*********************************
	logit dstar x1 x2 lsize i.lw i.nat i.rw shtter tottcpa numbase compm diverstot ///
		ly lpop op gov politym ethnm c.ethnm#c.ethnm, rob
	est store Mod1
	margins, dydx(_all) atmean post
	est store ME1
	logit dstar x1 x2 lsize i.lw i.nat i.rw shtter tottcpa numbase compm diverstot ///
		ly lpop op gov politym ethnm c.ethnm#c.ethnm i.eap i.eca i.lac i.na i.sas i.ssa, rob	
	est store Mod2
	margins, dydx(_all) atmean post
	est store ME2
	logit dstar _I* lsize i.lw i.nat i.rw shtter tottcpa numbase compm diverstot ///
		ly lpop op gov politym ethnm c.ethnm#c.ethnm i.eap i.eca i.lac i.na i.sas i.ssa, rob	
	est store Mod3
	margins, dydx(_all) atmean post
	est store ME3	
	logit dstar _I* lsize i.lw i.nat i.rw shtter tottcpa numbase compm diverstot ///
		ly lpop op gov politym ethnm c.ethnm#c.ethnm mem i.eap i.eca i.lac i.na i.sas i.ssa, rob
	est store Mod4
	margins, dydx(_all) atmean post
	est store ME4

	esttab Mod*, b(3) se(3) stats(N ll r2_p) star(* 0.10 ** 0.05 *** 0.01)		/* Table 4 */
	esttab ME*, margin b(3) se(3) stats(N) star(* 0.10 ** 0.05 *** 0.01)		/* Table 5 */
	estimates clear	
	
	
*********************************
*** Table 6
*********************************	
	xtset gid year
	logit dstar x1 x2 lsize i.lw i.nat i.rw l1.ttpk l1.tcpa numbase compm l1.divers ///
		l1.ly l1.lpop l1.op l1.gov l1.politym ethnm c.ethnm#c.ethnm ///
		i.eap i.eca i.lac i.na i.sas i.ssa lelv atropicm landlock, rob
	est store M1
	logit dstar _I* lsize i.lw i.nat i.rw l1.ttpk l1.tcpa numbase compm l1.divers ///
		l1.ly l1.lpop l1.op l1.gov l1.politym ethnm c.ethnm#c.ethnm ///
		i.eap i.eca i.lac i.na i.sas i.ssa lelv atropicm landlock, rob
	est store M2
	logit dstar _I* lsize i.lw i.nat i.rw l1.ttpk l1.tcpa numbase compm l1.divers ///
		l1.ly l1.lpop l1.op l1.politym ethnm c.ethnm#c.ethnm l1.mem ///
		i.eap i.eca i.lac i.na i.sas i.ssa lelv atropicm landlock, rob
	est store M3
	xtlogit dstar _I* lsize i.lw i.nat i.rw l1.ttpk l1.tcpa numbase compm l1.divers ///
		l1.ly l1.lpop l1.op l1.gov l1.politym ethnm c.ethnm#c.ethnm ///
		i.eap i.eca i.lac i.na i.sas i.ssa lelv atropicm landlock, re 
	est store M4	

	esttab M*, b(3) se(3) stats(N ll r2_p) star(* 0.10 ** 0.05 *** 0.01)
	estimates clear